またいらぬモジュールをつくってしまった。(´・ω・｀)
こういう一見不可能そうなことほど、燃えるんですよね。
//===================================================================
// 変数名を利用して変数にアクセスするモジュール
//===================================================================
//
// name = getvn(v1)
// 変数の名前を取得する
// v1 : 変数
//
// 変数v1のスクリプト上での名前を取得します。
// 大文字は全て小文字に変換されます（言語仕様）。
//
//-------------------------------------------------------------------
//
// dupptr_byname v1, name
// 指定した名前の変数の、クローン変数を作成する
// v1 : クローンにする変数
// name: クローン対象の変数名
//
// nameで指定した名前の変数の、クローン変数を作成します。
// 指定した名前の変数が、スクリプト内で
// 予め定義されている必要があります。
//
// 戻り値
// 0 : 成功
// 1 : 失敗
//
//===================================================================
//モジュールここから▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼
#uselib "user32"
#func global CharLowerA "CharLowerA" sptr
#module VNGetter
#deffunc local init_getvn
if f_init : return 0
f_init = 1
logmes "======================================"
logmes "外部からの内部変数アクセス用モジュール"
logmes " VNGetter"
logmes "--------------------------------------"
logmes "Date: 2012/09/24"
logmes "Author: てん"
logmes "======================================"
exist "obj"
if strsize < 0 {
logmes "objファイルが見つからないです。"
logmes "解析を断念します。(´・ω・｀)ｼｮﾎﾞｰﾝ…"
f_init = 0
return 1
}
sdim buf, strsize : bload "obj", buf
max_val = lpeek(buf, 8)
pt_ds = lpeek(buf, 24)
max_ds = lpeek(buf, 28)
pt_dinfo = lpeek(buf, 40)
max_dinfo = lpeek(buf, 44)
sdim DebugInfo, max_dinfo
memcpy DebugInfo, buf, max_dinfo, 0, pt_dinfo
sdim DataSection, max_ds
memcpy DataSection, buf, max_ds, 0, pt_ds
logmes "DataSection: "+strf("$%04X", pt_ds)+" - "+strf("$%04X", pt_ds+max_ds)
logmes ""+max_val+"個の変数を使用"
logmes "--------------------------------------"
sdim varnames, 64, max_val
i = 0
repeat max_dinfo
char = peek(DebugInfo, cnt)
if char = 255 : break
if char = 254 : continue cnt+1+3+2
if char = 253 {
offset = lpeek(DebugInfo, cnt+1) & 0x00FFFFFF
getstr varnames(i), DataSection, offset, $00
i++
continue cnt+1+3+2
}
if char == 252 : continue cnt+1+2
loop
repeat max_val
logmes "ID:"+strf("%03d", cnt)+" "+varnames(cnt)
loop
return 0
#defcfunc local getvid var v1
v1_pt = varptr(v1)
mref HSPCTX, 68
sdim Mem_var, 29
dupptr Mem_var, lpeek(HSPCTX, 44), max_val*48
res = -1
repeat max_val
v2_pt = lpeek(Mem_var, cnt*48+28)
if v1_pt = v2_pt : res=cnt : break
loop
return res
#defcfunc getvn var v1
id = getvid(v1)
if id = -1 : return "NOT FOUND"
return varnames(id)
#deffunc dupptr_byname var v1, str s1
s2 = s1 : CharLowerA varptr(s2)
id = -1
repeat max_val
if varnames(cnt) = s2 : id = cnt : break
loop
if id = -1 : dialog "NOT FOUND" : return 1
mref HSPCTX, 68
sdim Mem_var, 29
dupptr Mem_var, lpeek(HSPCTX, 44), max_val*48
dupptr v1, lpeek(Mem_var, id*48+28), lpeek(Mem_var, id*48+24), wpeek(Mem_var, id*48)
return 0
#global
init_getvn@VNGetter
//モジュールここまで▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲▲
//--------------------以下、サンプル----------------------------------------------------
#const BASE_X 400
#const BASE_Y 320
screen 0, BASE_X, BASE_Y
title "変数名を使った変数の管理"
font "メイリオ", 12
color $F0, $F0, $F0 : boxf
color
pos 20, 15 : mes "代入式( [変数名]=[値] の形式 空白・数式不可 )"
objsize 70, 25
pos BASE_X-90, 10 : button gosub "代入", *parse
sdim txt, 64 : txt = "a=30" : pos 20, 40 : input txt, BASE_X-40, 20
pos 20, 75 : mes "値を確認したい変数の名前"
sdim v_name, 64 : v_name="a" : pos ginfo_mesx+30, 75 : input v_name, BASE_X-(ginfo_mesx+50), 20
objsize BASE_X-40, 50
pos 20, 130 : button gosub "値を確認", *push
color $60, $60, $60 : boxf 20, 190, BASE_X-20, BASE_Y-20
color $C0, $F0, $FF : pos 30, 200
mes "スクリプト内で定義されている変数にしか使用できません。"
mes "例として a, b, c, d, e, f の6つの変数を定義しておきました。"
mes "\ta=30"
mes "\tb=20
mes "など、試してみて下さい（初期値は全て10になっています）。"
a=10 : b=10 : c=10
d=10 : e=10 : f=10
stop
*parse
split txt, "=", args
//args(0)に変数名、args(1)に値が入っている。
//変数vを、「args(0)で指定された名前の変数」の、クローン変数にする
dupptr_byname v, args(0)
//vへ代入。これで「args(0)で指定された名前の変数」に値が代入されたことになる。
v = int(args(1))
//式の削除
txt = "" : objprm 1, txt
return
*push
//変数vを、「v_nameで指定された名前の変数」の、クローン変数にする
dupptr_byname v, v_name
if stat : return //失敗（おそらく、指定した名前の変数が存在しなかったことに起因）
dialog v_name+"の値は"+v
return
inputに命令入力
