HSPTV!掲示板

こんにちは。
画面にCGを読み込み、それを中心点を中心にしたまま gzoom でズームアップする
方法で悩んでます。
pos 0,0:picload "tmp.jpg",1:;800*600サイズ画面ロード
repeat 70
gzoom 800 , 600 , 0 , cnt , cnt , 800-cnt , 600-cnt , 0
loop
こんな感じで書いてみたのですが、左上のほうにズームしていってしまいます。
ご教授くだされば幸いです。

こちらにサンプルがあるので参考にして下さい。
http://hsp.tv/play/pforum.php?mode=all&num=44510

合ってるのかどうか定かではありませんが、参考にさせて戴き、動かせました。
一応合ってるかわからないソースを貼っておきます。

gsel 2,0:gcopy 0,0,0,800,600:gsel 0,1
zx = 802 ; 最初に表示するＸサイズ
zy = 602 ; 最初に表示するＹサイズ
repeat 400
cx = 400 - zx /2 ; 表示するＸ座標
cy = 300 - zy /2 ; 表示するＹ座標
pos cx , cy
gzoom zx, zy, 2, 0, 0, 800, 600
zx + 20
zy + 20
loop

リンク先の私のサンプルは縦横が同じサイズの画像でないと正しく表示できないので
縦横比率を正しく表示できるサンプルを書いてみました。

    buffer 1, 800, 600  ;  コピー画像用バッファ
    color 255 : boxf

    src_x = 800  ; コピーする画像のＸサイズ
    src_y = 600  ; コピーする画像のＹサイズ
    
    zp_x = double(src_x) / 100  ; 1%分のＸサイズ
    zp_y = double(src_y) / 100  ; 1%分のＹサイズ
    
    screen 0, 800, 600
    zr_x = 10 ; 最初に表示するＸサイズの比率(%)
    zr_y = 10 ; 最初に表示するＹサイズの比率(%)
    
    center_x = 400  ;  表示の中心座標Ｘ
    center_y = 300  ;  表示の中心座標Ｙ
    
*main
    redraw 0
    color 255, 255, 255 : boxf
    
    xsize = int(zp_x * zr_x) ; 表示するＸサイズ
    ysize = int(zp_y * zr_y) ; 表示するＹサイズ
    
    cx = center_x - xsize / 2 ; 表示するＸ座標の計算(中心座標X=400)
    cy = center_y - ysize / 2 ; 表示するＹ座標の計算(中心座標Y=300)
    
    pos cx , cy
    gzoom xsize, ysize, 1, 0, 0, 800, 600
    
    stick key, 10  ;  上下キーで拡大縮小(1%〜100%)
    ;  ↓limitで1％〜100％までの値に限定
    if key & 2 : zr_x = limit(zr_x + 1, 1, 100) : zr_y = limit(zr_y + 1, 1, 100)
    if key & 8 : zr_x = limit(zr_x - 1, 1, 100) : zr_y = limit(zr_y - 1, 1, 100)
    
    title "表示比率=" + zr_x + "%  Ｘサイズ=" + xsize + "  Ｙサイズ=" + ysize
    redraw 1
    wait 1
    goto *main