HSPTV!掲示板

hspから棒読みちゃんに読ませるスクリプトはどのように描けばいいのでしょうか

Socketで、棒読みちゃんのポート(デフォルトでは50001)に、
データを送信することで、棒読みちゃんを制御できます。

とかいてあります

作ってみました。

#include "hspsock.as"

port=50001

sockopen 0, "localhost", port

text="こんにちは。HSP。"
speed = -1	;標準の設定
tone = -1	;標準の設定
volume = -1	;標準の設定
voice = 0	;標準の設定
code = 2	;Shift-JIS
len = strlen(text)	;文字数

sdim buf, 15 ;ってもHSPの仕様上64byte確保されるけど。
wpoke buf, 0, $0001
wpoke buf, 2, speed
wpoke buf, 4, tone
wpoke buf, 6, volume
wpoke buf, 8, voice
poke  buf,10, code
lpoke buf,11, len

sockputb buf, 0, 15, 0
sockput text, 0

bouyomichan\SampleSrc\Socket通信で読み上げ指示を送る(ネット経由可・C++版)\Src\BouyomiChanSample.cpp
を参考に作りました。
バグがあったらすいません。
textに読み上げたい文字を入れるだけで読み上げてもらえるはずです。

「こんにちわ。/ハスプ。」と言われても知りませんｗｗｗ

#include "hspsock.as"

port=50001

text="こんにちは。HSP。"

speed = -1	;標準の設定
tone = -1	;標準の設定
volume = -1	;標準の設定
voice = 0	;0:棒読みちゃん画面上の設定、1:女性1、2:女性2、3:男性1、4:男性2、5:中性、6:ロボット、7:機械1、8:機械2、10001〜:SAPI5 だそう。
code = 2	;0:UTF-8, 1:Unicode, 2:Shift-JIS
len = strlen(text)	;文字数

sdim buf, 15 ;ってもHSPの仕様上64byte確保されるけど。
wpoke buf, 0, $0001
wpoke buf, 2, speed
wpoke buf, 4, tone
wpoke buf, 6, volume
wpoke buf, 8, voice
poke  buf,10, code
lpoke buf,11, len

sockopen 0, "localhost", port
sockputb buf, 0, 15, 0
sockput text, 0
sockclose

もっとよく考えてから投稿すればよかったです。。。
いろいろと改善しました。

返信送れましたすいません！
ありがとうございます！