HSPTV!掲示板

getkeyを使って
キーボードのAを押したらAの文字が左から右へ流れる
キーボードのBを押したらBの文字が左から右へ流れる

このようなものはできたのですが、一つの文字が流れ終わるまで他の操作ができません。

Aが流れているときにキーボードのBを押したらBも流れる

このようなプログラムの組み方を教えてください。

A_X = -300 : B_X = 640
font "",480
repeat
getkey A,'A'
getkey B,'B'
if A=1 and A_Flg=0 : A_Flg = 1 ;[A]が押されていたら[A_Flg]に1を代入する
if B=1 and B_Flg=0 : B_Flg = 1
if A_Flg = 1 : A_X + 50 ;[A_Flg]に1が代入されていたら移動を行う
if B_Flg = 1 : B_X - 50 
if A_X >= 640 : A_Flg=0 : A_X = -300 ;Aが画面から見えなくなったら[A_Flg]を0に戻す
if B_X <= -300 : B_Flg=0 : B_X = 640
redraw 0
color 255,255,255 : boxf
color 0,0,0
pos A_X,0 : mes "A" ;表示をする
pos B_X,0 : mes "B"
redraw 1
await 30
loop

こういうことでしょうか？

参考になりました！
ありがとうございます。

誰か見ていたら教えてほしいのですが
画面外に出る前に文字が出るようにするにはどうすればよいのでしょうか？

>画面外に出る前に文字が出るようにする

とは文字の初期位置を画面内にしたいという意味ですか?
画面内に文字が出ているときでも、キーを押すと字の移動が
最初からやり直されるという意味ですか？

font "",480
dim A_Flg,100
dim B_Flg,100
dim A_X,100
dim B_X,100
repeat 100
A_X(cnt) = -300 : B_X(cnt) = 640
loop
repeat
getkey A,'A'
getkey B,'B'
if A=1 {
	if A_Lock = 0{;連続で出続けるのを防止する
		A_Lock = 1
		repeat 100
		if A_Flg(cnt) = 0 {
			A_Flg(cnt) = 1 ;[A]が押されていたら[A_Flg]に1を代入する
			break
		}
		loop
	}
}else : A_Lock = 0
if B=1 {
	if B_Lock = 0{
		B_Lock = 1
		repeat 100
		if B_Flg(cnt) = 0{
			B_Flg(cnt) = 1
			break
		}
		loop
	}
}else : B_Lock = 0
redraw 0
color 255,255,255 : boxf
color 0,0,0
repeat 100
if A_Flg(cnt) = 1 : A_X(cnt) + 50 ;[A_Flg]に1が代入されていたら移動を行う
if B_Flg(cnt) = 1 : B_X(cnt) - 50 
if A_X(cnt) >= 640 : A_Flg(cnt)=0 : A_X(cnt) = -300 ;Aが画面から見えなくなったら[A_Flg]を0に戻す
if B_X(cnt) <= -300 : B_Flg(cnt)=0 : B_X(cnt) = 640
if A_Flg(cnt) = 1 : pos A_X(cnt),0 : mes "A" ;表示をする
if B_Flg(cnt) = 1 : pos B_X(cnt),0 : mes "B"
loop
redraw 1
await 30
loop

こういうことでしょうか？
詳しくは配列型変数について調べてください。

ありがとうございました