HSPTV!掲示板

たとえば、2010/2/25から2010/3/5までの日数を計算するには、どうすればいいのでしょうか。
上記の例だと8と出るようにしたいのですが…
ぜひご教授くだされば幸いです。

SystemTimeToFileTimeを使えば簡単です。
64ビット整数を小数へ変換するとき誤差が出る可能性があるけど

#include "kernel32.as"
#define ctype MAKELONG(%1,%2) ((%1)|(%2)<<16) 
hiduke=MAKELONG(2010,2),MAKELONG(0,25),MAKELONG(0,0),MAKELONG(0,0)
hiduke2=MAKELONG(2010,3),MAKELONG(0,5),MAKELONG(0,0),MAKELONG(0,0)
jikan=0.0
jikan2=0.0
SystemTimeToFileTime varptr(hiduke),varptr(jikan)
SystemTimeToFileTime varptr(hiduke2),varptr(jikan2)
jikan=double(strf("%I64u",jikan))
jikan2=double(strf("%I64u",jikan2))
mes (jikan2-jikan)/(60e7*60*24)

Cのmktimeを使った方がもっと簡単だった

#uselib "msvcrt.dll"
#cfunc mktime "mktime" var
hiduke=0,0,0,25,2-1,2010-1900,0,0,0
hiduke2=0,0,0,5,3-1,2010-1900,0,0,0
mes (mktime(hiduke2)-mktime(hiduke))/(60*60*24)

標準命令のみのスクリ

http://hsp.tv/play/pforum.php?mode=search

mjdは日数計算の公式です。

検索結果のコピペはできないのか？
リンク先の内容は以下の通りです。

#module
#defcfunc mjd int yy,int mm,int dd
	if mm<3 :mm_=mm+12: yy_=yy-1:else:mm_=mm:yy_=yy
	md= 0.0+int(365.25 *yy_) +int(yy_/400) -int(yy_/100) +int(30.59*(mm_-2))+dd -678912
	return md
#global
screen 0,250,200
pos 60,
mes "yyyy  mm   dd"
objsize 30,20
pos 60,20
input yy1,,,4:in(0)=stat
input yy2,,,4:in(1)=stat
pos 100,20
input mm1,,,2:in(2)=stat
input mm2,,,2:in(3)=stat
pos 140,20
input dd1,,,2:in(4)=stat
input dd2,,,2:in(5)=stat
pos 60
objsize 110,20
input dummy,,,10:in(6)=stat
button "計算(C=B-A)",*calc
button "クリア",*clear
pos 45,23
mes "A\nB\nC"
*clear
	repeat 7
	objprm in(cnt),""
	loop
	stop
*calc
A=mjd(yy1,mm1,dd1)
B=mjd(yy2,mm2,dd2)
C=int(B-A)
objprm in(6),C
stop

> http://hsp.tv/play/pforum.php?mode=search

見たままですが、検索条件も検索結果の情報もアドレスには含まれていないようです。

いつもなら「サイト内検索」を使えば元のスレッドを発見できるのですが、なぜかヒットしません。
投稿日時をたよりに過去ログから地道に探すしかないようです。
http://hsp.tv/play/pforum.php?mode=pastwch&num=13795

過去ログの検索結果から元のスレッドへリンクしてくれるといいんですけどね…。

皆さんありがとうございました。
非常に助かりました。