多角形として考える場合
多角形とカーソルが重なっているかが問題になりますが
http://www.google.co.jp/search?q=多角形+内外判定&btnG=検索
でたくさん出てきました
考え方としては
調べたい点（ここではカーソル）から半直線を1本引き、
それが多角形の辺と交差する回数を数えます
回数が奇数回なら点は内部に、偶数回なら外部にあるというものです
とりあえず簡単なスクリプトを組んで見ました
//▼▼hedder▼▼
#const P_MAX 10
#const P_MAXmin P_MAX-1
#const SC_X 600
onclick gosub *PUT_POINT
//▲▲hedder▲▲
screen 0,SC_X,400
title "あと"+P_MAX+"回クリックしてください"
dim P_X,16 //多角形の頂点のX座標
dim P_Y,16 //多角形の頂点のY座標
*MAIN //多角形作成ルーチン
redraw 0
color 255,255,255 : boxf
//登録した点を順番に表示
color 255,0,0
if P_no!0{
repeat P_no
circle P_X(cnt)-5,P_Y(cnt)-5,P_X(cnt)+5,P_Y(cnt)+5
if cnt+1=P_no : break //要素オーバー防止
line P_X(cnt),P_Y(cnt),P_X(cnt+1),P_Y(cnt+1)
loop
line P_X(P_no-1),P_Y(P_no-1),mousex,mousey
}
redraw 1
wait 5 : goto *MAIN
*PUT_POINT //多角形の頂点を登録する
P_X(P_no)=mousex
P_Y(P_no)=mousey
P_no++
if P_no=P_MAX : onclick 0 : goto *MAIN2_1
title "あと"+int(P_MAX-P_no)+"回クリックしてください"
return
*MAIN2_1 //多角形描写ルーチン
Xm=mousex : Ym=mousey
redraw 0
color 255,255,255 : boxf
//多角形描写
color 255,0,0
repeat P_MAXmin
circle P_X(cnt)-5,P_Y(cnt)-5,P_X(cnt)+5,P_Y(cnt)+5
line P_X(cnt),P_Y(cnt),P_X(cnt+1),P_Y(cnt+1)
loop
circle P_X(P_MAXmin)-5,P_Y(9)-5,P_X(P_MAXmin)+5,P_Y(P_MAXmin)+5
line P_X(P_MAXmin),P_Y(P_MAXmin),P_X(0),P_Y(0)
//マウスの位置からレイを出す
color
circle Xm-5,Ym-5,Xm+5,Ym+5
line Xm,Ym,SC_X,Ym
redraw 1
*MAIN2_2 //内外判定ルーチン
count=0
//判定開始
repeat P_MAX
//交差判定対象とする辺の頂点
//点A(Xa,Ya),点B(Xb,Yb)の座標を参照する
Xa=P_X(cnt) : Ya=P_Y(cnt)
cn=cnt+1 : if cnt=P_MAXmin : cn=0
Xb=P_X(cn) : Yb=P_Y(cn)
//カーソルと点A,Bの距離を出す
Xam=Xa-Xm : Yam=Ya-Ym
Xbm=Xb-Xm : Ybm=Yb-Ym
//◆◆交差判定◆◆
//パターン��
if (Ya=Ym)&(Xa>Xm) : count++ : continue
//パターン��
if (Xam>0)&(Xbm>0)&(Yam*Ybm<0) : count++ : continue
//パターン��
if (Xam*Xbm<0)&(Yam*Ybm<0) {
if Xm<(Ym-Ya)*(Xa-Xb)/(Ya-Yb)+Xa : count++ : continue
}
//◆◆交差判定終了◆◆
loop
//判定終了 交差回数が奇数なら内部
if count\2 : title "IN" : else : title "OUT"
wait 5 : goto *MAIN2_1
このスクリプトでは
マウスカーソルから右に水平な直線（y=mousey)を引いて
その直線と辺の交差回数を数えています
交差判定のところにあるパターンとは
パターン� …樟�が頂点を通る
パターン�◆“縦蠅垢詈佞�2頂点が両方ともカーソルの右上に1個、右下に1個ずつある場合
パターン�� 判定する辺の2頂点がカーソルの左と右に1こずつある場合
の３パターンに分けて調べています
で、本題に戻りますが
地図を多角形の集合体として座標データ化して
上記の方法で今、どこにカーソルがあるのか調べる
という方法でいかがでしょうか
正直スクリプトも説明もやっつけ仕事なのでかなりわかりづらいと思います
わかりづらいとこあれば聞いてください
複雑な形状のクリッカブルマップについて
