HSPTV!掲示板

こんにちは、
windowsのプロセスバーのようにグラフの変化が右から左に流れるものを作ろうとしていますが、
要領がわかりません。
以下サンプル


;#include "ScrollBar.as"
#deffunc ScrollBar
;screen 1
;ScrollBar 500,399
mes "角度\tsin\t\tcos\t\ttan"
repeat 8
repeat 7200
kaku = 1.0 * cnt ;10度単位で
rad = kaku * 3.14151 / 180.0 ;角度kakuをラジアンradに変換
ss = sin(rad)
cc = cos(rad)
tt = tan(rad)
cs = int(ss*100)+150
; mes strf("%6.1f", kaku) + "\t" + ss + "\t" + cc + "\t" + tt + "\t" + cs
;cls 0
; mes cs
pos 100,100
pset cnt,cs
loop
await 10
;cls
loop
stop

よろしくどうぞ。

> windowsのプロセスバーのようにグラフの変化が右から左に流れるものを作ろうとしていますが、

「プログレスバー」の事でしょうか？
HSP開発wiki - HSP講座/ウィンドウ各部の名称
http://hspdev-wiki.net/?HSP%B9%D6%BA%C2%2F%A5%A6%A5%A3%A5%F3%A5%C9%A5%A6%B3%C6%C9%F4%A4%CE%CC%BE%BE%CE

もし、プログレスバーのことでしたら「プログレスバー HSP」でググってみてください。
一番上にLet's HSPでの解説ページが出てくると思います。

もし「スクロールバー」の事でしたら同じようにググるといろいろとプラグインやらモジュールやらが出てくるみたいですよ。

タスクマネージャのパフォーマンスのグラフのことだと予想。
過去の値を保持しておくことがポイント。

	#define NDATA	400	;過去NDATA時刻分の値を保持
	
	width NDATA, 250
	dim data, NDATA	;値を保持する変数。data(0)に最新の値、data(1)に1時刻前の値、･･･、data(NDATA-1)に(NDATA-1)時刻前の値を格納する
	
	repeat
		memcpy data, data, (NDATA-1)*4, 4, 0	;データ全体を1時刻分ずらす。data(0)に入っていた値をdata(1)に、data(1)に入っていた値をdata(2)に、･･･、data(NDATA-2)に入っていた値をdata(NDATA-1)に移す。
		;data(0) = int(sin(1.0 * cnt * 3.1416 / 180) * 100)	;data(0)に最新の値を代入
		data(0) = rnd(200)-100	;-100〜100の範囲の乱数を作成
		redraw 0
		color 255, 255, 255 : boxf
		;グリッドを描画
		color 192, 192, 192
		repeat 11
			line ginfo_winx, ginfo_winy/2+20*(cnt-5), 0, ginfo_winy/2+20*(cnt-5)
		loop
		c = cnt
		repeat ginfo_winx/20+1
			line ginfo_winx-20*cnt-(c\20), ginfo_winy/2+100, ginfo_winx-20*cnt-(c\20), ginfo_winy/2-100
		loop
		;グラフを描画
		color 0, 255, 0
		pos ginfo_winx, ginfo_winy/2+data(0)
		repeat NDATA-1
			line ginfo_winx-cnt-1, ginfo_winy/2+data(cnt+1)	;ウィンドウ右端が最新の値。古い値ほど左に
		loop
		redraw 1
		wait 1
	loop

ありがとうございました。
これを実現したかったのです。
今後ともよろしくどうぞ。

ｏｋでした。